AWK(1)

NAME
awk - pattern scanning and processing language

SYNOPSIS
awk [ -Fc ] [ prog ] [ parameters ][ file ] ...

DESCRIPTION
Awk scans each input file for lines that match any of a set of patterns specified in prog. With each pattern in prog there can be an associated action that will be performed when a line of a file matches the pattern. The set of patterns may appear literally as prog, or in a file specified as -f file.

Files are read in order; if there are no files, the standard input is read. The file name `-' means the standard input. Each line is matched against the pattern portion of every pattern-action statement; the associated action is performed for each matched pattern.

An input line is made up of fields separated by white space. (This default can be changed by using FS, vide infra.) The fields are denoted $1, $2, ... ; $0 refers to the entire line.

A pattern-action statement has the form

    pattern { action }

A missing { action } means print the line; a missing pattern always matches.

An action is a sequence of statements. A statement can be one of the following:

	if ( conditional ) statement [ else statement ]
	while ( conditional ) statement
	for ( expression ; conditional ; expression ) statement
	for ( variable in array ) statement
	break
	continue
	{ [ statement ] ... }
	variable = expression
	print [ expression-list ] [ >expression ]
	print [ expression-list ] [ >>expression ]
	print [ expression-list ] [ |expression ]
	printf format [ , expression-list ] [ >expression ]
	printf format [ , expression-list ] [ >>expression ]
	printf format [ , expression-list ] [ |expression ]
	next	(skip remaining patterns on this input line)
	exit	(skip the rest of the input)
	#	(comment; ignore text up to end of line)

Statements are terminated by semicolons, newlines or right braces. Long statements may be split across multiple lines by ending each partial line with backslash, `\'. An empty expression-list stands for the whole line. Expressions take on string or numeric values as appropriate, and are built using the operators +, -, *, /, %, and concatenation (indicated by a blank). The C operators ++, --, +=, -=, *=, /=, and %= are also available in expressions.

Variables may be scalars, array elements (denoted x[i]) or fields. String constants are quoted "...". Variables may be initialized to specific values from the command line by including arguments of the form name=value before any file arguments. Otherwise all variables are initialized to the null string.

Array subscripts may be any string, not necessarily numeric; this allows for a form of associative memory. Arrays may be traversed by means of the second form of the for loop shown above. In this the variable is set to each of the valid indexes of array in turn. The order in which the indexes are returned is undefined.

The print statement prints its arguments on the standard output, separated by the current output field separator, and terminated by the output record separator. The printf statement formats its expression list according to the format (see printf(3S)).

If >expression is appended to either of these commands, the output is sent to the file named by the expression. If >>expression is present, the file is appended. If |expression is present, the output is sent to the standard input of the named command. Files and pipes are kept open for the duration of the awk program; subsequent output goes to the same file or pipe provided the spelling of expression is identical. Up to ten commands and/or files may be used.

The built-in function length returns the length of its argument taken as a string, or of the whole line if no argument. There are also built-in functions exp, log, sqrt, and int, which perform exponential, natural logarithm, square root and truncation to integer respectively.

The function substr(s, m, n) returns the n-character substring of s that begins at position m. The function split(s1, arr, s2) assigns the fields of string s1 to successive elements of array arr using the characters of string s2 as field separators. Assignments start at arr[1]. The function index(s1, s2) returns the leftmost position at which the string s2 occurs in s1, or 0 if it does not occur. String positions for index and substr start at 1.

The getline function (note: no parentheses) immediately reads the next input record and sets $0 and NR accordingly. This does not alter control flow within the awk program, and the line fetched will not be compared against any of the patterns. The getline function returns 0 on end of file, 1 otherwise.

The function sprintf(fmt, expr, expr, ...) formats the expressions according to the printf(3S) format given by fmt and returns the resulting string.

Patterns are arbitrary Boolean combinations (!, ||, &&, and parentheses) of regular expressions and relational expressions. Regular expressions must be surrounded by slashes and are as in egrep. Isolated regular expressions in a pattern apply to the entire line. Regular expressions may also occur in relational expressions.

A pattern may consist of two patterns separated by a comma; in this case, the action is performed for all lines between an occurrence of the first pattern and the next occurrence of the second.

A relational expression is one of the following:

	expression matchop regular-expression
	expression relop expression

where a relop is any of the six relational operators in C, and a matchop is either ~ (for contains) or !~ (for does not contain). A conditional is an arithmetic expression, a relational expression, or a Boolean combination of these.

The special patterns BEGIN and END may be used to capture control before the first input line is read and after the last. BEGIN must be the first pattern, END the last.

A single character c may be used to separate the fields by starting the program with

    BEGIN { FS = "c" }

or by using the -Fc option.

Other variable names with special meanings include NF, the number of fields in the current record; NR, the ordinal number of the current record; FILENAME, the name of the current input file; RS, the input record separator (default newline); OFS, the output field separator (default blank); ORS, the output record separator (default newline); and OFMT, the output format for numbers (default "%.6g").

EXAMPLES

Print lines longer than 72 characters:

	length > 72

Print first two fields in opposite order:

	{ print $2, $1 }

Add up first column, print sum and average:

		{ s += $1 }
	END	{ print "sum is", s, " average is", s/NR }

Print fields in reverse order:

	{ for (i = NF; i > 0; --i) print $i }

Print all lines between start/stop pairs:

	/start/, /stop/

Print all lines whose first field is different from previous one:

	$1 != prev { print; prev = $1 }

SEE ALSO

lex(1), sed(1)
A. V. Aho, B. W. Kernighan, P. J. Weinberger, Awk - a pattern scanning and processing language

BUGS
There are no explicit conversions between numbers and strings. To force an expression to be treated as a number add 0 to it; to force it to be treated as a string concatenate "" to it.

Within a character class regular expression (ie "[ ... ]" ) awk treats '\' followed by ']' as an escaped ']', for reasons of historic compatibility.